#define AppVersion "0.1.0"
#define PublishRoot "..\artifacts\installer-publish"

[Setup]
AppId={{8B2EAF78-2B11-4E55-9C39-7A6E4E7A4B7D}
AppName=WxAgent
AppVersion={#AppVersion}
AppPublisher=WxAgent
SetupIconFile={#PublishRoot}\wxagent.ico
DefaultDirName={localappdata}\Programs\WxAgent
DisableDirPage=no
DefaultGroupName=WxAgent
OutputDir=..\artifacts\setup
OutputBaseFilename=WxAgent-Setup
Compression=lzma2
SolidCompression=yes
WizardStyle=modern
PrivilegesRequired=lowest
ArchitecturesAllowed=x64compatible
ArchitecturesInstallIn64BitMode=x64compatible
DisableProgramGroupPage=yes
CloseApplications=yes
RestartApplications=no
Uninstallable=yes

[Files]
Source: "{#PublishRoot}\WxAgent.Tray.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#PublishRoot}\WxAgent.Host.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#PublishRoot}\wwwroot\*"; DestDir: "{app}\wwwroot"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "{#PublishRoot}\wxagent.ico"; DestDir: "{app}"; Flags: ignoreversion

[Tasks]
Name: "autostart"; Description: "登录 Windows 后自动启动 WxAgent"; GroupDescription: "启动选项:"; Flags: checkedonce

[Icons]
Name: "{autoprograms}\WxAgent"; Filename: "{app}\WxAgent.Tray.exe"; WorkingDir: "{app}"
Name: "{userdesktop}\WxAgent"; Filename: "{app}\WxAgent.Tray.exe"; WorkingDir: "{app}"
Name: "{userstartup}\WxAgent"; Filename: "{app}\WxAgent.Tray.exe"; WorkingDir: "{app}"; Tasks: autostart

[Run]
Filename: "{sys}\schtasks.exe"; Parameters: "/delete /tn ""WxAgent"" /f"; Flags: runhidden waituntilterminated
Filename: "{sys}\taskkill.exe"; Parameters: "/IM WxAgent.Host.exe /F"; Flags: runhidden waituntilterminated
Filename: "{sys}\taskkill.exe"; Parameters: "/IM WxAgent.Tray.exe /F"; Flags: runhidden waituntilterminated
Filename: "{app}\WxAgent.Tray.exe"; WorkingDir: "{app}"; Description: "启动 WxAgent 托盘程序；双击后在服务设置中配置"; Flags: nowait postinstall skipifsilent

[UninstallRun]
Filename: "{sys}\schtasks.exe"; Parameters: "/delete /tn ""WxAgent"" /f"; Flags: runhidden waituntilterminated; RunOnceId: "DeleteWxAgentTask"
Filename: "{sys}\taskkill.exe"; Parameters: "/IM WxAgent.Tray.exe /F"; Flags: runhidden; RunOnceId: "StopWxAgentTray"
Filename: "{sys}\taskkill.exe"; Parameters: "/IM WxAgent.Host.exe /F"; Flags: runhidden; RunOnceId: "StopWxAgentHost"